Функция СУММЕСЛИ в Excel с примерами


В предыдущей статье мы рассмотрели синтаксис функции СУММЕСЛИ в Excel, теперь давайте закрепим знания на практике при помощи ряда примеров формулы СУММЕСЛИ:

СУММЕСЛИ в Excel примеры с логическими операторами (больше, меньше или равно)

Давайте рассмотрим несколько примеров формул СУММЕСЛИ, которые вы можете использовать для суммирования значений для условий больше чем, меньше чем или равно заданному значению.

Примечание. Обратите внимание, что в формулах Excel СУММЕСЛИ оператор сравнения, за которым следует число или текст, всегда должен быть заключен в двойные кавычки ("").

Критерий

Оператор

Пример формулы СУММЕСЛИ

Описание

Сумма, если больше

=СУММЕСЛИ(A2:A10; ">5")

Суммирует значения больше 5 в ячейках A2:A10.

Сумма, если меньше

=СУММЕСЛИ(A2:A10; "<10"; B2:B10)

Суммирует значения в ячейках B2:B10, если соответствующее значение в столбце A меньше 10.

Сумма, если равно

=

(можно не указывать)

=СУММЕСЛИ(A2:A10; "="&D1)

или

=СУММЕСЛИ(A2:A10;D1)

Суммирует значения в ячейках A2:A10, которые равны значению в ячейке D1.

Сумма, если не равно

<> 

=СУММЕСЛИ(A2:A10; "<>"&D1; B2:B10)

Суммирует значения в ячейках B2:B10, если соответствующая ячейка в столбце A не равна значению в ячейке D1.

Сумма если больше или равно

>=

=СУММЕСЛИ(A2:A10; ">=5")

Суммирует значения, которые больше или равны 5 в диапазоне A2:A10.

Сумма если меньше или равно

<=

=СУММЕСЛИ(A2:A10; "<=10"; B2:B10)

Суммирует значения в ячейках B2:B10, если соответствующее значение в столбце A меньше либо равно 10.

СУММЕСЛИ в Excel примеры с текстовым критерием

Помимо чисел, функция СУММЕСЛИ позволяет суммировать значения в зависимости от того, содержит ли соответствующая ячейка в другом столбце определенный текст или нет. Рассмотрим примеры СУММЕСЛИ в Excel с текстом.

Обратите внимание, что вам понадобятся разные формулы СУММЕСЛИ для точного и частичного совпадения, как показано в таблице ниже.

Критерий

Пример формулы СУММЕСЛИ

Описание

Сумма, если равно

Точное совпадение:

=СУММЕСЛИ(A2:A8; "бананы"; C2:C8)

Суммирует значения в ячейках C2:C8, если соответствующая ячейка в столбце A содержит точное слово «бананы» и никакие другие слова или символы. Ячейки, содержащие «зеленые бананы», «бананы зеленые» или «бананы!» не будут считаться.

Частичное совпадение:

=СУММЕСЛИ(A2:A8; "*бананы*"; C2:C8)

Суммирует значения в ячейках C2:C8, если соответствующая ячейка в столбце A содержит слово «бананы», отдельно или в сочетании с любыми другими словами. Ячейки, содержащие «зеленые бананы» или «бананы зеленые», будут учитываться для суммирования.

Сумма, если не равно

Точное совпадение:

=СУММЕСЛИ(A2:A8; "<>бананы"; C2:C8)

Суммирует значения в ячейках C2:C8, если соответствующая ячейка в столбце A содержит любое значение, отличное от слова «бананы». Если ячейка содержит «бананы» вместе с некоторыми другими словами или символами, такими как «желтые бананы» или «бананы желтые», такие ячейки будут учитываться для суммирования.

Частичное совпадение:

=СУММЕСЛИ(A2:A8; "<>*бананы*"; C2:C8)

Суммирует значения в ячейках C2:C8, если соответствующая ячейка в столбце A не содержит слова «бананы», отдельно или в сочетании с любыми другими словами. Ячейки, содержащие «желтые бананы» или «бананы желтые», не суммируются.

Для получения дополнительной информации о частичном совпадении см. пункт СУММЕСЛИ примеры формул с подстановочными знаками.

А теперь, давайте посмотрим пример формулы «Сумма, если не равно» в действии. Как показано на изображении ниже, формула суммирует количество всех продуктов, кроме «Банана Дамский пальчик»:

=СУММЕСЛИ(A2:A8; "<>Банан Дамский пальчик"; C2:C8)

3-funktciia-summesli-v-excel

Функция СУММЕСЛИ в Excel с примерами – Пример функции СУММЕСЛИ с проверкой на неравенство

Примечание. Как и большинство других функций Excel, СУММЕСЛИ нечувствительна к регистру, что означает, что «<> бананы», «<> Бананы» и «<> БАНАНЫ» будут давать точно такой же результат.

СУММЕСЛИ в Excel примеры операторов сравнения со ссылками на ячейки

Если вы хотите получить более универсальную формулу Excel СУММЕСЛИ, вы можете заменить числовое или текстовое значение в критериях ссылкой на ячейку, например:

= СУММЕСЛИ(A2:A8; "<>"&F1; C2:C8)

В этом случае вам не придется менять формулу СУММЕСЛИ, основанную на другом критерии – вы просто вводите новое значение в ссылочной ячейке.

4-funktciia-summesli-v-excel

Функция СУММЕСЛИ в Excel с примерами – Пример функции СУММЕСЛИ, суммирование исключая значение в ячейке F1

Примечание. Когда вы используете логическое выражение с ссылкой на ячейку, вы должны использовать двойные кавычки (""), чтобы начать текстовую строку и амперсанд (&), чтобы объединить и завершить строку, например «<>» и F1.

Оператор «равенства» (=) можно не использовать до ссылки на ячейку, поэтому обе приведенные ниже формулы эквивалентны и правильны:

Формула 1: =СУММЕСЛИ(A2:A8; "=" & F1; C2:C8)

Формула 2: =СУММЕСЛИ(A2:A8; F1; C2:C8)

СУММЕСЛИ примеры формул с подстановочными знаками

Если вы намерены условно суммировать ячейки на основе «текстовых» критериев и хотите суммировать путем частичного совпадения, вам нужно использовать подстановочные знаки в формуле СУММЕСЛИ.

Доступны следующие подстановочные знаки:

Звездочка (*) - представляет любое количество символов

Знак вопроса (?) - представляет один символ в определенном месте

 

Пример 1. Суммирование значений, основанные на частичном совпадении

Предположим, вы хотите суммировать количество, относящиеся ко всем видам бананов. Следующие формулы СУММЕСЛИ будут очень эффективны в таких случаях: 

=СУММЕСЛИ(A2:A8; "*бананы*";C2:C8) - критерий включает текст, заключенный в звездочки (*).

 

=СУММЕСЛИ(A2:A8; "*"&F1&"*"; C2:C8) - критерий включает ссылку на ячейку, заключенную в звездочки, обратите внимание на использование амперсанда (&) до и после ссылки на ячейку для конкатенации строки.

5-funktciia-summesli-v-excel

Функция СУММЕСЛИ в Excel с примерами – Пример функции СУММЕСЛИ с подстановочными знаками для суммирования по частичному совпадению

Если вы хотите считать только те ячейки, которые начинаются или заканчиваются определенным текстом, добавьте только один * до или после текста:

=СУММЕСЛИ(A2:A8; "бананы*"; C2:C8) - значения суммы в C2:C8, если соответствующая ячейка в столбце A начинается со слова «бананы».

 

=СУММЕСЛИ(A2:A8; "*бананы"; C2:C8) - значения суммы в C2:C8, если соответствующая ячейка в столбце A заканчивается словом «бананы».

6-funktciia-summesli-v-excel

Функция СУММЕСЛИ в Excel с примерами – Пример использования функции СУММЕСЛИ с текстовым условием

 

Пример 2. Суммирование по заданному количеству символов

Если вы хотите суммировать некоторые значения длиной в шесть букв, вы должны использовать следующую формулу:

=СУММЕСЛИ(A2:A8; "??????"; C2:C8)

7-funktciia-summesli-v-excel

Функция СУММЕСЛИ в Excel с примерами – Пример функции СУММЕСЛИ с условием суммирования, если длина текстовой строки в шесть букв

 

Пример 3. Сумма ячеек, соответствующих текстовым значениям

Если ваш рабочий лист содержит разные типы данных, и вы хотите только суммировать ячейки, соответствующие текстовым значениям, пригодится следующая формула СУММЕСЛИ:

=СУММЕСЛИ(A2:A8; "?*"; C2:C8) – суммирует значения из ячеек C2:C8, если соответствующая ячейка в столбце A содержит не менее 1 символа.

 

=СУММЕСЛИ(A2:A8; "*"; C2:C8) – учитывает пустые ячейки, содержащие строки нулевой длины, возвращаемые некоторыми другими формулами, например ="".

Обе приведенные выше формулы игнорируют нетекстовые значения, такие как ошибки, логические значения, числа и даты.

 

Пример 4. Использование * или ? как обычные символы

Если вы хотите использовать либо *, либо ? для обработки в функции СУММЕСЛИ как литерала, а не подстановочного знака, то используйте перед этим знаком тильду (~). Например, следующая формула СУММЕСЛИ просуммирует значения в ячейках C2:C8, если ячейка в столбце A в той же строке содержит знак вопроса:

=СУММЕСЛИ(A2: A8; "~?"; C2: C8)

8-funktciia-summesli-v-excel

Функция СУММЕСЛИ в Excel с примерами – Пример функции СУММЕСЛИ с суммированием значений, соответствующие знаку вопроса в другом столбце

СУММЕСЛИ в Excel примеры с датами

Как правило, функцию СУММЕСЛИ используют для условного суммирования значений на основе дат так же, как и с текстовыми и числовыми критериями.

Если вы хотите суммировать значения, соответствующие датам, которые больше или меньше указанной вами даты, используйте операторы сравнения, которые мы рассматривали выше. Ниже приведены примеры формул Excel СУММЕСЛИ с датами:

Критерий

Пример формулы СУММЕСЛИ

Описание

Сумма по определенной дате

=СУММЕСЛИ(B2:B9;"29.10.2017";C2:C9)

Суммирует значения в ячейках C2:C9, если соответствующая дата в столбце B равна 29.10.2017.

Сумма, если дата больше либо равна заданной в формуле дате

=СУММЕСЛИ(B2:B9;">=29.10.2017";C2:C9)

Суммирует значения в ячейках C2:C9, если соответствующая дата в столбце B больше или равна 29.10.2017.

Сумма, если дата больше даты, указанной в ячейке

=СУММЕСЛИ(B2:B9;">"&F1;C2:C9)

Суммирует значения в ячейках C2:C9, если соответствующая дата в столбце B больше даты, указанной в ячейке F1.

Если вы хотите суммировать значения на основе текущей даты, вам необходимо использовать СУММЕСЛИ в сочетании с функцией СЕГОДНЯ(), как показано ниже:

Критерий

Пример формулы СУММЕСЛИ

Суммирование значений, за текущую дату

=СУММЕСЛИ(B2:B9; СЕГОДНЯ (); C2:C9)

Суммирование значений, меньше текущей даты, то есть до сегодняшнего дня.

=СУММЕСЛИ(B2:B9; "<"&СЕГОДНЯ(); C2:C9)

Суммирование значений, больше текущей даты, то есть будущие даты относительно сегодняшнего дня.

=СУММЕСЛИ(B2:B9; ">"& СЕГОДНЯ(); C2:C9)

Суммирование значений за неделю от текущей даты. (т.е. сегодня + 7 дней).

=СУММЕСЛИ(B2:B9; "="&СЕГОДНЯ()+7; C2:C9)

Изображение ниже показывает, как вы можете использовать последнюю формулу, чтобы найти общее количество всех продуктов, которые будут отправлены через неделю:

9-funktciia-summesli-v-excel

Функция СУММЕСЛИ в Excel с примерами – Пример функции СУММЕСЛИ с суммированием количества продуктов, которые будут отправлены через неделю

СУММЕСЛИ в заданном диапазоне дат

Если вам необходимо суммировать значения между двумя датами, то необходимо использовать комбинацию, а точнее разницу двух функций СУММЕСЛИ. В версиях старше Excel 2007 вы можете использовать функцию СУММЕСЛИМН, которая позволяет использовать несколько условий. Эту функцию мы рассмотрим в следующей статье. А так как данная статья посвящена функции СУММЕСЛИ, то приведем пример использования СУММЕСЛИ в диапазоне дат:

=СУММЕСЛИ(B2:B9; ">=01.11.2017"; C2:C9) - СУММЕСЛИ(B2:B9; ">=01.12.2017"; C2:C9)

Эта формула суммирует значения в ячейках C2:C9, если дата в столбце B находится между 1 ноября 2017 года и 30 ноября 2017, включительно.

10-funktciia-summesli-v-excel

Функция СУММЕСЛИ в Excel с примерами – Пример функции СУММЕСЛИ дата в диапазоне

Эта формула может показаться немного сложной с первого взгляда, но при более близком рассмотрении это выглядит довольно просто. Первая функция СУММЕСЛИ объединяет все ячейки в C2:C9, где соответствующая ячейка в столбце B больше или равна дате начала (в данном примере 1 ноября). Затем вам просто нужно вычесть значения, которые попадают после даты окончания (30 ноября), с помощью второй функции СУММЕСЛИ.

В данной статье мы разобрали множество примеров функции СУММЕСЛИ с разными условиями, такими как числовые, текстовые, даты и другие. В следующей статье мы рассмотрим функцию СУММЕСЛИМН, которая является аналогом функции СУММЕСЛИ с несколькими условиями.


Категории: MS Excel  

Об этой статье

funktciia-summesli-v-excel-s-primerami-avatar
2017-11-29 15:30:20
3300
user
MS Office; Office 2003; Office 2013; MS Excel; Excel 2003; Excel 2010; Excel 2013; Функции Excel; Office 2007; Office 2010; Office 2016; Excel 2016; Подсчет суммы; Excel 2007;
В данной статье рассмотрено, как использовать функцию СУММЕСЛИ в Excel, разобрано множество примеров функции СУММЕСЛИ с разными условиями, такими как числовые, текстовые, даты и другие.